Símbolos en fórmulas de Excel: 8 que evitan errores
Aprende a usar 8 símbolos en fórmulas de Excel: el punto, el apóstrofo, el espacio, el asterisco, el signo de interrogación, la virgulilla, el signo de dólar y el ampersand para evitar errores y crear fórmulas más flexibles.
¿Qué vas a ver aquí?
Introducción
¿Alguna vez escribiste 0001 en una celda y Excel te mostró un simple 1? ¿O creaste una fórmula que llenó tu tabla de ceros en las filas vacías? Muchos de estos problemas se resuelven con símbolos en fórmulas de Excel que casi nadie usa. Son caracteres pequeños, pero cambian por completo el resultado.
En este artículo vas a aprender a usar 8 de ellos con ejemplos prácticos. Verás cómo evitar ceros innecesarios, impedir que Excel convierta tus datos en fechas y contar textos con comodines. También aprenderás a fijar referencias y a unir nombres en una sola celda.
Para descargar los archivos utilizados en la clase, completa con tu e-mail:
¡No te enviaremos ningún tipo de spam! Hashtag Capacitaciones es una empresa comprometida con la protección de tus datos. Si tienes alguna duda, contáctanos.
Al final te espera un reto para poner todo en práctica. Antes de empezar, aquí tienes un resumen de los 8 símbolos:
| Símbolo | Nombre | Para qué sirve | Ejemplo |
|---|---|---|---|
| . | Punto | Ignorar las filas vacías al final de un rango | =B2:.B17-C2:.C17 |
| ‘ | Apóstrofo | Hacer que Excel trate el dato como texto | ‘0001 |
| ( ) | Espacio | Usar solo la intersección de dos rangos | =SUMA(B4:B10 B5:D6) |
| * | Asterisco | Representar cualquier cantidad de caracteres | “*@hashtag.com” |
| ? | Signo de interrogación | Representar un solo carácter | “?????” |
| ~ | Virgulilla | Buscar un ? o un * real | “~?” |
| $ | Signo de dólar | Fijar una columna, una fila o ambas | =$C5*D$4 |
| & | Ampersand | Unir textos y celdas | =A2&” “&B2 |
Cómo controlar rangos con el punto y el espacio
Los dos primeros símbolos cambian la forma en que Excel lee un rango. El punto le dice qué celdas ignorar. El espacio le dice qué celdas tomar.
Cómo quitar los ceros de las filas vacías con el punto (:.)
Imagina una lista de productos con el valor total en la columna B y el costo total en la columna C. Quieres calcular la ganancia en la columna D. Para que la fórmula también cubra los productos que agregues después, seleccionas algunas filas de más, hasta la 17:
=B2:B17-C2:C17
La fórmula funciona, pero hay un problema. Tus datos terminan en la fila 13, así que las filas 14 a 17 muestran un 0 que ensucia el informe.
La solución es agregar un punto justo después de los dos puntos de cada rango:
=B2:.B17-C2:.C17
Ahora Excel ignora las filas vacías del final. Escribes la fórmula solo en la celda D2 y el resultado se extiende hacia abajo. Si agregas en la fila 14 un producto con 100.000 € de valor y 50.000 € de costo, la ganancia de 50.000 € aparece sola.
Este punto tiene nombre: se llama referencia de recorte y es un atajo de la función RECORTAR.RANGO. Puedes ver todos los detalles en la documentación de Microsoft sobre RECORTAR.RANGO. Existen tres variantes:
| Escritura | Qué recorta |
|---|---|
| B2:.B17 | Las celdas vacías del final |
| B2.:B17 | Las celdas vacías del inicio |
| B2.:.B17 | Las celdas vacías del inicio y del final |
Como el resultado ocupa varias celdas, funciona igual que cualquier matriz dinámica. Si quieres entender ese comportamiento, revisa nuestra guía sobre los rangos de desbordamiento en Excel.
Ojo: esta funcionalidad es reciente y está disponible en Microsoft 365. En versiones anteriores, Excel no reconoce la fórmula.
Cómo sumar solo la intersección de dos rangos con el espacio
Ahora imagina el rango B4:D10 lleno con el número 2. Quieres sumar dos bloques: la columna B4:B10 y el bloque B5:D6. Para eso, separas los rangos con punto y coma:
=SUMA(B4:B10;B5:D6)
El resultado es 26: 14 del primer rango más 12 del segundo.
Ahora cambia el punto y coma por un espacio:
=SUMA(B4:B10 B5:D6)
El resultado pasa a ser 4. El espacio es el operador de intersección, así que Excel solo considera las celdas que pertenecen a los dos rangos al mismo tiempo. En este caso, son B5 y B6.
Si los rangos no se cruzan en ninguna celda, Excel devuelve el error #¡NULO!.
Cómo usar el apóstrofo para que Excel no cambie lo que escribes
Excel siempre intenta interpretar lo que escribes. A veces eso es útil, pero otras veces arruina tus datos. El apóstrofo (‘) le dice a Excel: “esto es texto, no lo cambies”.
El apóstrofo no aparece en la celda. Solo lo verás en la barra de fórmulas.
| Caso | Sin apóstrofo | Con apóstrofo |
|---|---|---|
| Códigos con ceros a la izquierda | Escribes 0001 y Excel muestra 1 | Escribes ‘0001 y Excel muestra 0001 |
| Rangos de notas | Escribes 1-3 y Excel muestra una fecha (1 de marzo) | Escribes ‘1-3 y Excel muestra 1-3 |
| Mostrar una fórmula | Escribes =SUMA(E2:E4) y Excel muestra 6 | Escribes ‘=SUMA(E2:E4) y Excel muestra la fórmula como texto |
El primer caso es muy común con los IDs de empleados. Si usas códigos de cuatro dígitos, el empleado 101 será 0101 y toda la lista queda uniforme.
El tercer caso es ideal para documentar tu trabajo. Calcula el resultado en una celda y, en la celda de al lado, pega la misma fórmula con un apóstrofo delante. Así cualquier persona ve el resultado y la fórmula que lo generó.
Un cuidado importante: con el apóstrofo, el dato pasa a ser texto. Excel puede marcarlo con un triángulo verde de “Número almacenado como texto”, y ese valor no sirve para cálculos. Si necesitas que el código siga siendo número, usa un formato personalizado. Presiona Ctrl+1, elige la categoría Personalizada en la ventana Formato de celdas y escribe 0000.
Microsoft explica otras alternativas en su guía para mantener los ceros iniciales.
Cómo usar los comodines *, ? y ~ con CONTAR.SI
Los comodines son caracteres que representan otros caracteres dentro de un criterio. Con ellos puedes contar textos que contienen una palabra, que tienen cierta cantidad de letras o que incluyen símbolos especiales. Siempre van entre comillas, dentro del criterio de la función.
Cómo contar textos que contienen una palabra con el asterisco
Tienes una lista de 7 empleados con sus nombres en A2:A8 y sus correos en C2:C8. Quieres saber cuántos usan el correo corporativo @hashtag.com. Tu primer intento sería este:
=CONTAR.SI(C2:C8;”@hashtag.com”)
El resultado es 0. ¿Por qué? Porque Excel busca celdas que sean exactamente “@hashtag.com”, y ningún correo es solo eso. Todos tienen un nombre antes del arroba.
El asterisco representa cualquier cantidad de caracteres. Si lo pones antes del arroba, Excel entiende que puede haber cualquier texto antes:
=CONTAR.SI(C2:C8;”*@hashtag.com”)
Ahora el resultado es 4.
La posición del asterisco cambia todo. Mira lo que pasa al contar los nombres con “María” en una lista que incluye a “Ana María Liñares” y “María Benes”:
| Criterio | Qué busca | Resultado |
|---|---|---|
| “*María” | Textos que terminan con María | 0 |
| “María*” | Textos que empiezan con María | 1 |
| “*María*” | Textos que contienen María en cualquier posición | 2 |
La regla es simple: pon el asterisco del lado donde puede haber más texto.
Un detalle que causa muchos errores: CONTAR.SI distingue las tildes. Si escribes “*Maria*” sin tilde, el resultado será 0. En cambio, no distingue mayúsculas de minúsculas.
El asterisco tiene otros usos, como multiplicar valores o filtrar datos. Los reunimos en 🔗 nuestro artículo sobre los usos principales del asterisco en Excel.
Cómo contar textos con un número exacto de caracteres con ?
El signo de interrogación representa exactamente un carácter. Si escribes cinco signos seguidos, Excel busca textos de cinco caracteres.
En una lista con los nombres Agustina, Diego, Mikel, Emilia, María y Manuela, esta fórmula cuenta los que tienen cinco letras:
=CONTAR.SI(A2:A7;”?????”)
El resultado es 3: Diego, Mikel y María.
También puedes combinar letras y comodines. Por ejemplo, “M????” cuenta los nombres de cinco letras que empiezan con M. En esta lista, el resultado es 2: Mikel y María.
Cómo contar un ? real con la virgulilla (~)
Aquí aparece un problema curioso. ¿Qué pasa si tu lista contiene signos de interrogación y quieres contarlos?
Imagina una columna con estos valores: Agustina, Diego, ?, Emilia, ? y M. Si usas “?” como criterio, el resultado es 3, no 2. Excel cuenta todas las celdas con un solo carácter, y la “M” también lo es.
La virgulilla (~) le dice a Excel que el carácter siguiente no es un comodín, sino un símbolo real:
=CONTAR.SI(A2:A7;”~?”)
Ahora el resultado es 2.
Lo mismo funciona con ~* para buscar un asterisco real y con ~~ para buscar la propia virgulilla.
Y si un nombre termina en signo de interrogación, como “Mikel?”, combina la virgulilla con el asterisco. El criterio “~?” solo cuenta las celdas que son exactamente “?”. En cambio, “*~?” cuenta cualquier texto que termine en “?”, así que en una lista con “Mikel?” y “?” el resultado es 2.
En la documentación de Microsoft, este símbolo aparece con el nombre de “tilde”. Puedes ver la tabla completa en la guía oficial de caracteres comodín de Microsoft.
¿No encuentras la virgulilla en tu teclado? Puedes copiarla de cualquier texto y pegarla en tu fórmula.
Cómo fijar referencias con el signo de dólar ($)
Quieres simular cuánto ingresaría tu empresa con distintas cantidades y precios. Las cantidades están en C5:C8 (150, 300, 450 y 600 unidades). Los precios están en D4:G4 (8 €, 10 €, 12 € y 15 €).
En la celda D5 escribes:
=C5*D4
El resultado es 1.200 €. Aquí el asterisco cumple otra función: es el operador de multiplicación.
Ahora arrastras la fórmula hacia la derecha con el controlador de relleno, el cuadrito verde de la esquina inferior derecha de la celda. En E5 esperabas 1.500 € (150 × 10 €), pero aparece 12.000 €.
¿Qué pasó? Al arrastrar la fórmula, todas las referencias se movieron una columna. La C5 se convirtió en D5, que contiene 1.200 €, en lugar de las 150 unidades.
Para evitarlo, fija la referencia. Haz clic sobre C5 dentro de la fórmula y presiona F4. Excel agrega el signo de dólar y la referencia queda como $C$5. En algunas computadoras portátiles debes presionar Fn+F4.
Con $C$5, todo funciona hacia la derecha. Pero al arrastrar hacia abajo, la fórmula sigue multiplicando siempre 150 unidades, y tú necesitas 300, 450 y 600.
Este tema es tan importante que aparece entre las preguntas de Excel más frecuentes en entrevistas de trabajo.
Cómo crear referencias mixtas para una tabla de escenarios
La solución está en fijar solo lo necesario. Cada vez que presionas F4, la referencia cambia en este orden:
| Pulsaciones de F4 | Referencia | Qué queda fijo |
|---|---|---|
| 0 | C5 | Nada (referencia relativa) |
| 1 | $C$5 | Columna y fila (referencia absoluta) |
| 2 | C$5 | Solo la fila (referencia mixta) |
| 3 | $C5 | Solo la columna (referencia mixta) |
Las cantidades siempre están en la columna C, pero cambian de fila. Por eso necesitas $C5. Los precios siempre están en la fila 4, pero cambian de columna. Por eso necesitas D$4.
La fórmula final en D5 queda así:
=$C5*D$4
Arrastra hacia la derecha y luego hacia abajo. La tabla queda completa y correcta:
Haz la prueba: haz clic en F7. La fórmula multiplica 450 unidades por 12 €, que da 5.400 €.
Si quieres profundizar, Microsoft explica cada tipo en su guía sobre referencias relativas, absolutas y mixtas.
Cómo unir textos con el ampersand (&)
Tienes los nombres en la columna A y los apellidos en la columna B. Quieres el nombre completo en la columna C. El ampersand (&) une textos y celdas:
=A2&B2
El resultado es “AgustinaBlasi”, todo junto. Falta el espacio. Para agregarlo, escríbelo entre comillas y únelo con otro ampersand:
=A2&” “&B2
Ahora el resultado es “Agustina Blasi”. Para copiar la fórmula a toda la lista, haz doble clic en el controlador de relleno. Excel la extiende hasta el último dato.
Existen funciones que hacen lo mismo, como CONCAT y UNIRCADENAS. Las explicamos en nuestra guía de funciones de texto en Excel.
Reto: cómo corregir un BUSCARV combinando & y *
Llegó la hora de unir lo que aprendiste. Tienes una tabla con nombres completos en la columna A y el área de cada empleado en la columna B. En la celda D2 hay una lista desplegable con los nombres de pila: Agustina, Diego, Mikel, Emilia, María y Manuela.
En E2, esta fórmula debería devolver el área del empleado elegido:
=BUSCARV(D2;A:B;2;0)
Pero el resultado es #N/D. Excel busca “Agustina”, y en la columna A solo existe “Agustina Blasi”.
Intenta resolverlo antes de seguir leyendo. Pista: necesitas dos de los símbolos de este artículo.
Solución:
=BUSCARV(D2&”*”;A:B;2;0)
El resultado es Marketing. El ampersand une el asterisco al nombre elegido, así que Excel busca “Agustina*”: cualquier texto que empiece con Agustina. BUSCARV acepta comodines cuando el último argumento es 0, es decir, en la búsqueda exacta.
Ten en cuenta que si dos empleados tienen el mismo nombre, BUSCARV devuelve el primero que encuentra.
Si quieres crear listas desplegables como la de D2, sigue nuestra guía de la herramienta Validación de datos en Excel.
Conclusión
Ahora conoces 8 símbolos en fórmulas de Excel que resuelven problemas reales del día a día. El punto y el espacio controlan qué celdas usa tu fórmula y el apóstrofo protege tus datos. Los comodines hacen búsquedas flexibles, el signo de dólar fija referencias y el ampersand une textos. Combinados, como en el reto, son todavía más poderosos.
Si te gustó aprender así, paso a paso y con ejemplos prácticos, imagina dominar Excel de principio a fin. En el curso Excel Impresionante vas desde lo básico hasta el nivel avanzado, con ejercicios enfocados en el mercado laboral. ¡Te esperamos!
Si prefieres este contenido en formato de video tutorial, mira el vídeo abajo o visita nuestro canal de YouTube!
Preguntas frecuentes sobre los símbolos en fórmulas de Excel
¿Por qué Excel convierte “1-3” en una fecha?
Excel interpreta las combinaciones de número, guion y número como fechas. Para evitarlo, escribe un apóstrofo antes del dato, como en ‘1-3. Otra opción es aplicar el formato Texto a las celdas antes de escribir.
¿Cuál es la diferencia entre $A$1, A$1 y $A1?
$A$1 fija la columna y la fila, así que nunca cambia al arrastrar la fórmula. A$1 fija solo la fila y $A1 fija solo la columna. Puedes alternar entre los tipos presionando F4 con la referencia seleccionada.
¿Los comodines funcionan en otras funciones además de CONTAR.SI?
Sí. Funcionan en SUMAR.SI, PROMEDIO.SI, BUSCARV y BUSCARX (en este caso, con el modo de coincidencia 2). También sirven con varios criterios a la vez, como verás en nuestra guía de CONTAR.SI.CONJUNTO y SUMAR.SI.CONJUNTO.
Hashtag Capacitaciones
¡Para ver más publicaciones de Excel, haz clic aquí!
Últimas publicaciones de Excel
- Símbolos en fórmulas de Excel: 8 que evitan errores
Aprende a usar 8 símbolos en fórmulas de Excel: el punto, el apóstrofo, el espacio, el asterisco, el signo de interrogación, la virgulilla, el signo de dólar y el ampersand para evitar errores y crear fórmulas más flexibles. - Ejercicios de Excel con Claude: practica a tu medida
Dos niveles: 1- Generar ejercicios de Excel con Claude a través de un prompt; 2- Crear una habilidad en Claude para que los arme de la misma manera sin tener que repetir las instrucciones. - KPIs de ventas en Excel: 6 indicadores paso a paso
Aprende a calcular los KPIs de ventas en Excel desde cero: ventas totales, ticket promedio, cumplimiento de meta y más, con tablas dinámicas.
